SQL Server 2016 introduced sys.dm_db_column_store_row_group_physical_stats system view for finding the information on Columnstore row groups and related fragmentation.
This is an extended version of sys.column_store_row_groups.

Using this system view, you can find information like total number of rows physically stored, and a column for the number of rows marked as deleted.

SELECT 
	OBJECT_NAME([i].[object_id]) AS TableName
	,[i].[name] AS IndexName	
	,[csrgps].[state_desc]
	,[csrgps].[total_rows]
	,[csrgps].[deleted_rows]
	,[csrgps].[size_in_bytes]
	,[csrgps].[trim_reason_desc]
	,[csrgps].[transition_to_compressed_state_desc]
	,[csrgps].[has_vertipaq_optimization]	
	,[csrgps].[created_time]
	,[csrgps].[closed_time]
	,100 * (ISNULL(csrgps.[deleted_rows],0)) / total_rows AS 'IsFragmentation'
FROM sys.indexes AS i
INNER JOIN sys.dm_db_column_store_row_group_physical_stats AS csrgps
	ON [i].[object_id] = [csrgps].[object_id] 
		AND [i].index_id = [csrgps].index_id  
ORDER BY [TableName], [IndexName] 
GO

The statistics of the Database Objects are playing very important role because Query Optimizer uses these statistics to choose the best execution plan.

Query Optimizer requires different information like: number of rows, index information, change count and others.

The updated statistics always give a better performance so we should find last updated statistics time and if it is outdated, we should update statistics for that particular object.

I am going to share three different scripts to find information about the information of tables and indexes.

Using DBCC:

-- This dbcc works up to SQL Server 2012.
DBCC SHOW_STATISTICS ('Table_Name', 'Index_Name') 
GO

Using sys.stats:

SELECT 
	OBJECT_NAME(object_id) AS ObjectName
	,name AS StatisticName
	,STATS_DATE(object_id, stats_id) AS StatisticUpdateDate	
FROM sys.stats;
GO

Using sys.indexes:

SELECT 
    SCHEMA_NAME(SCHEMA_ID) AS SchemaName
    ,OBJECT_NAME(o.OBJECT_ID) AS ObjectName
    ,i.name AS IndexName
    ,STATS_DATE(o.OBJECT_ID,i.index_id) AS StatisticUpdateDate 
FROM sys.indexes AS i 
JOIN sys.objects AS o 
	ON i.object_id = o.object_id 
WHERE o.object_id > 100 AND index_id > 0 
  AND is_ms_shipped = 0
GO

In this post, I am going to share one T-SQL script to find duplicate and redundant Indexes of the SQL Server.

I have found some of the junior and intermediate Database Developers, who are creating multiple duplicates indexes which are decreasing the overall performance of the database.

Now the job of the Database Administrator is to find and remove duplicate indexes from the database.

I have prepared a small demonstration by creating some of duplicate indexes and provided script to find that duplicate indexes.

First, create a sample table:

CREATE TABLE dbo.tbl_Students
(
	StudID INT IDENTITY(1,1)
	,FirstName VARCHAR(50)
	,LastName VARCHAR(50)
	,DOB DATETIME
	,CONSTRAINT pk_tbl_Students_StudID PRIMARY KEY(StudID)
)
GO

Create duplicate indexes on LastName column:

CREATE NONCLUSTERED INDEX idx_tbl_Students_LastName_FirstName_DOB
ON dbo.tbl_Students (LastName,FirstName,DOB)
GO

CREATE NONCLUSTERED INDEX idx_tbl_Students_LastName_FirstName
ON dbo.tbl_Students (LastName,FirstName)
GO

CREATE NONCLUSTERED INDEX idx_tbl_Students_LastName
ON dbo.tbl_Students (LastName)
GO

Sample SELECT statements:
Below, both SELECT statements are using only one index (idx_tbl_Students_LastName_FirstName_DOB) because LastName column is duplicated in all the indexes.

SELECT *FROM dbo.tbl_Students WHERE LastName ='Patel' AND FirstName = 'Anvesh'
GO
SELECT *FROM dbo.tbl_Students WHERE LastName ='Patel'
GO

Script to find Duplicate Indexes:

SELECT
	s.Name + '.' + t.Name AS TableName	
	,i.name AS IndexName1	
	,DupliIDX.name AS IndexName2
	,c.name AS ColumnNae
FROM sys.tables AS t 
JOIN sys.indexes AS i
	ON t.object_id = i.object_id
JOIN sys.index_columns ic 
	ON ic.object_id = i.object_id 
		AND ic.index_id = i.index_id 
		AND ic.index_column_id = 1  
JOIN sys.columns AS c 
	ON c.object_id = ic.object_id 
		AND c.column_id = ic.column_id      
JOIN sys.schemas AS s 
	ON t.schema_id = s.schema_id
CROSS APPLY
(
	SELECT 
	   ind.index_id
	   ,ind.name
	FROM sys.indexes AS ind 
	JOIN sys.index_columns AS ico 
	   ON ico.object_id = ind.object_id
	   AND ico.index_id = ind.index_id
	   AND ico.index_column_id = 1  
	WHERE ind.object_id = i.object_id 
	   AND ind.index_id > i.index_id
	   AND ico.column_id = ic.column_id
) DupliIDX     
ORDER BY
    s.name,t.name,i.index_id
GO

The Result:

In this post, I am sharing one T-SQL script to find a Table which has more than 10 Indexes in SQL Server.

More Indexes on a Table, are creating a performance issue because Indexes also require dedicated CPU I/O for writing it into the Index Pages.
More Indexes will slow down the insertion or any other DML operation of that particular Table.

Below is a script to find out tables which are having more indexes:
You can change the value of @threshold.

DECLARE @threshold INT;
SET @threshold = 10;

SELECT
	[s].[name] + '.' + [t].[name] AS TableName
FROM sys.tables AS t
INNER JOIN sys.schemas AS s
	ON [t].[schema_id] = [s].[schema_id]
WHERE EXISTS
(
	SELECT 1 FROM sys.indexes AS i
    WHERE [i].[object_id] = [t].[object_id]
    GROUP BY [i].[object_id]
    HAVING COUNT(*) > @threshold
)
GO

In this post, I am sharing a script for a Database Administrator to find SQL Server Heap Tables which are not having a clustered index.

A Table without a clustered index is called as Heap Table and Data is stored in the Heap without specifying an order.

I have also published one article on, What is Heap Table?
You can visit this article here:

Sometimes, database developer forgets to apply cluster index on a particular table and after that, the same table may have a lot of data which affect the query performance without having a clustered index.

Below is a script:

SELECT 
	OBJECT_NAME(object_id) AS TableName
	,type_desc AS TableType
	,allow_row_locks
	,allow_page_locks
FROM sys.indexes 
WHERE index_id = 0

In this post, I am sharing a SQL script to find different operational stats of Indexes.

This script is handy for DBA because sometimes it requires concluding that total how many time indexes are updated.

Using below script, you can find the total number of INSERT, UPDATE and DELETE stats for indexes.

SELECT 
	OBJECT_NAME(DDIOS.OBJECT_ID) AS ObjectName
	,I.[NAME] AS IndexName
	,DDIOS.LEAF_INSERT_COUNT AS TotalInsertCount
	,DDIOS.LEAF_UPDATE_COUNT AS TotalUpdateCount
	,DDIOS.LEAF_DELETE_COUNT AS TotalDeleteCount
FROM SYS.DM_DB_INDEX_OPERATIONAL_STATS (NULL,NULL,NULL,NULL ) AS DDIOS
INNER JOIN SYS.INDEXES AS I 
	ON I.OBJECT_ID = DDIOS.OBJECT_ID
	AND I.INDEX_ID = DDIOS.INDEX_ID 
WHERE  OBJECTPROPERTY(DDIOS.OBJECT_ID,'IsUserTable') = 1